;***********************************************************
; Port A 動作チェックプログラム（３）
; Port A の発光ダイオードを交互に点滅させる
; 全ポートを出力させるためには、
; RA4ポートがプルアップされていること
;***********************************************************

	LIST		P=PIC16F877	; プロセッサの種別指定
	INCLUDE		"P16F877.INC"	; インクルードファイルの指定
        
;***********************************************************
;  変数定義とレジスタ割付
;***********************************************************

COUNT	EQU	20H		; ループカウンタ
COUNT1	EQU	21H		; ループカウンタ1
COUNT2	EQU	22H		; ループカウンタ2
COUNT3	EQU	23H		; ループカウンタ3
COUNT4	EQU	24H		; ループカウンタ4

	ORG	0		; プログラムの開始番地の指定

;***********************************************************
;  入出力ピン初期化
;***********************************************************

	BSF	STATUS,RP0	; Bank 1 へ切替
	CLRF	TRISA		; PortA 全ポートを出力に設定
	BCF	STATUS,RP0	; Bank 0 へ戻る

;***********************************************************
; メインプログラム
;***********************************************************

MAINLP
	MOVLW	2AH		; 00101010 を Wreg にロードする
	MOVWF	PORTA		; PORTAへWregのデータを出力
	CALL	TIME1S		; １秒一定時間待つ

	MOVLW	15H		; 00010101 を Wreg にロードする
	MOVWF	PORTA		; PORTAへWregのデータを出力
	CALL	TIME1S		; １秒一定時間待つ

	GOTO	MAINLP		; ＯＮ−ＯＦＦを繰り返す

;***********  サブルーチン群  ******************************

;１００μｓ遅延サブルーチン（２０ＭＨｚクロック時）

TIME100
	MOVLW	0A5H		; 1サイクル A5H=165
	MOVWF	COUNT		; 1サイクル
	NOP			; 1サイクル 微調整ダミー
	NOP			; 1サイクル 微調整ダミー
LOOP
	DECFSZ	COUNT,F		; 1×(165-1)＋2 = 166サイクル
	GOTO	LOOP		; 2×(165-1) = 328サイクル
	RETURN			; 2サイクル


;１０ｍｓ遅延サブルーチン（２０ＭＨｚクロック時）

TIME10M
	MOVLW	63H		; 1サイクル 63H=99
	MOVWF	COUNT1		; 1サイクル
	NOP			; 1サイクル 微調整ダミー
	NOP			; 1サイクル 微調整ダミー
LOOP1
	CALL	TIME100		; （2＋500）×99＝49698サイクル
	DECFSZ	COUNT1,F	; 1×(99-1)＋2 = 100サイクル
	GOTO	LOOP1		; 2×(99-1) = 196サイクル
	RETURN			; 2サイクル


;１ｓ遅延サブルーチン（２０ＭＨｚクロック時）

TIME1S
	MOVLW	63H		; 1サイクル 63H=99
	MOVWF	COUNT2		; 1サイクル
	MOVLW	62H		; 1サイクル 62H=98
	MOVWF	COUNT3		; 1サイクル
	MOVLW	03H		; 1サイクル 03H=3
	MOVWF	COUNT4		; 1サイクル
	NOP			; 1サイクル 微調整ダミー
LOOP2
	CALL	TIME10M		;（2＋50000）×99＝4950198サイクル
	DECFSZ	COUNT2,F	; 1×(99-1)＋2 = 100サイクル
	GOTO	LOOP2		; 2×(99-1) = 196サイクル
LOOP3
	CALL	TIME100		;（2＋500)×98＝49196
	DECFSZ	COUNT3,F	; 1×(98-1)＋2 = 99サイクル
	GOTO	LOOP3		; 2×(98-1) = 194サイクル
LOOP4
	DECFSZ	COUNT4,F	; 1×(3-1)＋2 = 4サイクル
	GOTO	LOOP4		; 2×(3-1) = 4サイクル
	RETURN			; 2サイクル

	END